Fixed vim and zsh

vim/plugins/syntastic/syntax_checkers/sh/bashate.vim

@@ -0,0 +1,48 @@
+"============================================================================
+"File:        bashate.vim
+"Description: Bash script style checking plugin for syntastic.vim
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+
+if exists('g:loaded_syntastic_sh_bashate_checker')
+    finish
+endif
+let g:loaded_syntastic_sh_bashate_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_sh_bashate_GetLocList() dict
+    let makeprg = self.makeprgBuild({})
+
+    let errorformat =
+        \ '%EE%n: %m,' .
+        \ '%Z - %f%\s%\+: L%l,' .
+        \ '%-G%.%#'
+
+    let loclist = SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat,
+        \ 'subtype': 'Style',
+        \ 'returns': [0, 1] })
+
+    for e in loclist
+        let e['text'] = substitute(e['text'], "\\m: '.*", '', '')
+    endfor
+
+    return loclist
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'sh',
+    \ 'name': 'bashate' })
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set sw=4 sts=4 et fdm=marker:

vim/plugins/syntastic/syntax_checkers/sh/checkbashisms.vim

@@ -0,0 +1,42 @@
+"============================================================================
+"File:        checkbashisms.vim
+"Description: Shell script syntax/style checking plugin for syntastic.vim
+"Notes:       checkbashisms.pl can be downloaded from
+"             http://debian.inode.at/debian/pool/main/d/devscripts/
+"             as part of the devscripts package.
+"============================================================================
+
+if exists('g:loaded_syntastic_sh_checkbashisms_checker')
+    finish
+endif
+let g:loaded_syntastic_sh_checkbashisms_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_sh_checkbashisms_GetLocList() dict
+    let makeprg = self.makeprgBuild({ 'args': '-fx' })
+
+    let errorformat =
+        \ '%-Gscript %f is already a bash script; skipping,' .
+        \ '%Eerror: %f: %m\, opened in line %l,' .
+        \ '%Eerror: %f: %m,' .
+        \ '%Ecannot open script %f for reading: %m,' .
+        \ '%Wscript %f %m,%C%.# lines,' .
+        \ '%Wpossible bashism in %f line %l (%m):,%C%.%#,%Z.%#,' .
+        \ '%-G%.%#'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat,
+        \ 'subtype': 'Style' })
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'sh',
+    \ 'name': 'checkbashisms' })
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set sw=4 sts=4 et fdm=marker:

vim/plugins/syntastic/syntax_checkers/sh/sh.vim

@@ -0,0 +1,95 @@
+"============================================================================
+"File:        sh.vim
+"Description: Syntax checking plugin for syntastic.vim
+"Maintainer:  Gregor Uhlenheuer <kongo2002 at gmail dot com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+
+if exists('g:loaded_syntastic_sh_sh_checker')
+    finish
+endif
+let g:loaded_syntastic_sh_sh_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_sh_sh_IsAvailable() dict " {{{1
+    let buf = bufnr('')
+    call self.log('shell =', s:GetShell(buf))
+    return s:IsShellValid(buf)
+endfunction " }}}1
+
+function! SyntaxCheckers_sh_sh_GetLocList() dict " {{{1
+    let buf = bufnr('')
+    if s:GetShell(buf) ==# 'zsh'
+        return s:ForwardToZshChecker()
+    endif
+
+    if !s:IsShellValid(buf)
+        return []
+    endif
+
+    let makeprg = self.makeprgBuild({
+        \ 'exe': s:GetShell(buf),
+        \ 'args_after': '-n' })
+
+    let errorformat = '%f: line %l: %m'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat })
+endfunction " }}}1
+
+" Utilities {{{1
+
+function! s:GetShell(buf) " {{{2
+    let shell = syntastic#util#getbufvar(a:buf, 'shell')
+    if shell ==# ''
+        let shebang = syntastic#util#parseShebang(a:buf)['exe']
+        if shebang !=# ''
+            if shebang[-strlen('bash'):-1] ==# 'bash'
+                let shell = 'bash'
+            elseif shebang[-strlen('zsh'):-1] ==# 'zsh'
+                let shell = 'zsh'
+            elseif shebang[-strlen('sh'):-1] ==# 'sh'
+                let shell = 'sh'
+            endif
+        endif
+        " try to use env variable in case no shebang could be found
+        if shell ==# ''
+            let shell = fnamemodify($SHELL, ':t')
+        endif
+    endif
+    return shell
+endfunction " }}}2
+
+function! s:IsShellValid(buf) " {{{2
+    let shell = s:GetShell(a:buf)
+    return shell !=# '' && executable(shell)
+endfunction " }}}2
+
+function! s:ForwardToZshChecker() " {{{2
+    let registry = g:SyntasticRegistry.Instance()
+    let zsh_checkers = registry.getCheckersAvailable('zsh', ['zsh'])
+    if !empty(zsh_checkers)
+        return zsh_checkers[0].getLocListRaw()
+    else
+        return []
+    endif
+endfunction " }}}2
+
+" }}}1
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'sh',
+    \ 'name': 'sh' })
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set sw=4 sts=4 et fdm=marker:

vim/plugins/syntastic/syntax_checkers/sh/shellcheck.vim

@@ -0,0 +1,67 @@
+"============================================================================
+"File:        shellcheck.vim
+"Description: Shell script syntax/style checking plugin for syntastic.vim
+"============================================================================
+
+if exists('g:loaded_syntastic_sh_shellcheck_checker')
+    finish
+endif
+let g:loaded_syntastic_sh_shellcheck_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_sh_shellcheck_GetLocList() dict " {{{1
+    let buf = bufnr('')
+    let makeprg = self.makeprgBuild({
+        \ 'args': s:GetShell(buf),
+        \ 'args_after': '-f gcc' })
+
+    let errorformat =
+        \ '%f:%l:%c: %trror: %m,' .
+        \ '%f:%l:%c: %tarning: %m,' .
+        \ '%f:%l:%c: %tote: %m'
+
+    let loclist = SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat,
+        \ 'returns': [0, 1] })
+
+    for e in loclist
+        if e['type'] ==? 'n'
+            let e['type'] = 'w'
+            let e['subtype'] = 'Style'
+        endif
+    endfor
+
+    return loclist
+endfunction " }}}1
+
+" Utilities {{{1
+
+function! s:GetShell(buf) " {{{2
+    let sh = ''
+
+    if syntastic#util#parseShebang(a:buf)['exe'] ==# ''
+        if syntastic#util#bufRawVar(a:buf, 'is_kornshell', 0) || syntastic#util#bufRawVar(a:buf, 'is_posix', 0)
+            let sh = 'ksh'
+        elseif syntastic#util#bufRawVar(a:buf, 'is_bash', 0)
+            let sh = 'bash'
+        elseif syntastic#util#bufRawVar(a:buf, 'is_sh', 0)
+            let sh = 'sh'
+        endif
+    endif
+
+    return sh !=# '' ? '-s ' . sh : ''
+endfunction " }}}2
+
+" }}}1
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'sh',
+    \ 'name': 'shellcheck' })
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set sw=4 sts=4 et fdm=marker: