Fixed vim and zsh

vim/plugins/syntastic/syntax_checkers/rst/proselint.vim

@@ -0,0 +1,23 @@
+"============================================================================
+"File:        proselint.vim
+"Description: Syntax checking plugin for syntastic
+"Maintainer:  LCD 47 <lcd047 at gmail dot com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+
+if exists('g:loaded_syntastic_rst_proselint_checker')
+    finish
+endif
+let g:loaded_syntastic_rst_proselint_checker = 1
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'rst',
+    \ 'name': 'proselint',
+    \ 'redirect': 'text/proselint'})
+
+" vim: set sw=4 sts=4 et fdm=marker:

vim/plugins/syntastic/syntax_checkers/rst/rst2pseudoxml.vim

@@ -0,0 +1,65 @@
+"============================================================================
+"File:        rst.vim
+"Description: Syntax checking plugin for docutils' reStructuredText files
+"Maintainer:  James Rowe <jnrowe at gmail dot com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+
+" We use rst2pseudoxml.py, as it is ever so marginally faster than the other
+" rst2${x} tools in docutils.
+
+if exists('g:loaded_syntastic_rst_rst2pseudoxml_checker')
+    finish
+endif
+let g:loaded_syntastic_rst_rst2pseudoxml_checker = 1
+
+let s:rst2pseudoxml = (executable('rst2pseudoxml.py') && !syntastic#util#isRunningWindows()) ? 'rst2pseudoxml.py' : 'rst2pseudoxml'
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_rst_rst2pseudoxml_IsAvailable() dict
+    call self.log('exec =', self.getExec())
+    return executable(self.getExec())
+endfunction
+
+function! SyntaxCheckers_rst_rst2pseudoxml_GetLocList() dict
+    let makeprg = self.makeprgBuild({
+        \ 'args_after': '--report=2 --exit-status=1',
+        \ 'tail': syntastic#util#DevNull() })
+
+    let errorformat =
+        \ '%f:%l: (%t%\w%\+/%\d%\+) %m,'.
+        \ '%f:: (%t%\w%\+/%\d%\+) %m,'.
+        \ '%-G%.%#'
+
+    let loclist = SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat })
+
+    for e in loclist
+        if e['type'] ==? 'I'
+            let e['type'] = 'W'
+            let e['subtype'] = 'Style'
+        else
+            let e['type'] = 'E'
+        endif
+    endfor
+
+    return loclist
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'rst',
+    \ 'name': 'rst2pseudoxml',
+    \ 'exec': s:rst2pseudoxml })
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set sw=4 sts=4 et fdm=marker:

vim/plugins/syntastic/syntax_checkers/rst/rstcheck.vim

@@ -0,0 +1,50 @@
+"============================================================================
+"File:        rstcheck.vim
+"Description: Syntax checking for reStructuredText and embedded code blocks
+"Authors:     Steven Myint <git@stevenmyint.com>
+"
+"============================================================================
+
+if exists('g:loaded_syntastic_rst_rstcheck_checker')
+    finish
+endif
+let g:loaded_syntastic_rst_rstcheck_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_rst_rstcheck_GetLocList() dict
+    let makeprg = self.makeprgBuild({})
+
+    let errorformat =
+        \ '%f:%l: (%tNFO/1) %m,'.
+        \ '%f:%l: (%tARNING/2) %m,'.
+        \ '%f:%l: (%tRROR/3) %m,'.
+        \ '%f:%l: (%tEVERE/4) %m,'.
+        \ '%-G%.%#'
+
+    let loclist = SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat,
+        \ 'returns': [0, 1] })
+
+    for e in loclist
+        if e['type'] ==? 'S'
+            let e['type'] = 'E'
+        elseif e['type'] ==? 'I'
+            let e['type'] = 'W'
+            let e['subtype'] = 'Style'
+        endif
+    endfor
+
+    return loclist
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'rst',
+    \ 'name': 'rstcheck'})
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set sw=4 sts=4 et fdm=marker:

vim/plugins/syntastic/syntax_checkers/rst/sphinx.vim

@@ -0,0 +1,81 @@
+"============================================================================
+"File:        sphinx.vim
+"Description: Syntax checking plugin for Sphinx reStructuredText files
+"Maintainer:  Buck Evan <buck dot 2019 at gmail dot com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+
+if exists("g:loaded_syntastic_rst_sphinx_checker")
+    finish
+endif
+let g:loaded_syntastic_rst_sphinx_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+let s:sphinx_cache_location = syntastic#util#tmpdir()
+lockvar s:sphinx_cache_location
+
+augroup syntastic
+    autocmd VimLeave * call syntastic#util#rmrf(s:sphinx_cache_location)
+augroup END
+
+function! SyntaxCheckers_rst_sphinx_GetLocList() dict
+    let buf = bufnr('')
+
+    let srcdir = syntastic#util#bufVar(buf, 'rst_sphinx_source_dir')
+    call self.log('syntastic_rst_sphinx_source_dir =', srcdir)
+    if srcdir ==# ''
+        let config = syntastic#util#findFileInParent('conf.py',  fnamemodify(bufname(buf), ':p:h'))
+        if config ==# '' || !filereadable(config)
+            call self.log('conf.py file not found')
+            return []
+        endif
+        let srcdir = fnamemodify(config, ':p:h')
+    endif
+
+    let confdir = syntastic#util#bufVar(buf, 'rst_sphinx_config_dir')
+    call self.log('syntastic_rst_sphinx_config_dir =', confdir)
+    if confdir ==# ''
+        let config = syntastic#util#findFileInParent('conf.py',  fnamemodify(bufname(buf), ':p:h'))
+        let confdir = (config !=# '' && filereadable(config)) ? fnamemodify(config, ':p:h') : srcdir
+    endif
+
+    let makeprg = self.makeprgBuild({
+        \ 'args': '-n -E',
+        \ 'args_after': '-q -N -b pseudoxml -c ' . syntastic#util#shescape(confdir),
+        \ 'fname': syntastic#util#shescape(srcdir),
+        \ 'fname_after': syntastic#util#shescape(s:sphinx_cache_location) })
+
+    let errorformat =
+        \ '%E%f:%l: SEVER%t: %m,' .
+        \ '%f:%l: %tRROR: %m,' .
+        \ '%f:%l: %tARNING: %m,' .
+        \ '%E%f:: SEVER%t: %m,' .
+        \ '%f:: %tRROR: %m,' .
+        \ '%f:: %tARNING: %m,' .
+        \ '%trror: %m,' .
+        \ '%+C%.%#'
+
+    let loclist = SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat,
+        \ 'returns': [0] })
+
+    return loclist
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'rst',
+    \ 'name': 'sphinx',
+    \ 'exec': 'sphinx-build' })
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set sw=4 sts=4 et fdm=marker: